/**
 * CrazyWeaver
 * Interpolation test doodle
 * (see FlyingBall.interpol())
 *
 * Joerg Reuter, jore[at]stachelig[dot]de
 * Creative Commons Attribution 3.0 license
 * http://stachelig.de
 * Heads up: http://sol.gfxile.net/interpolation
 */

int MAX_X = 640;
int MAX_Y = 360;
int NUM_BALLS = 10;
int DURATION = 40;

FlyingBall[] balls  = new FlyingBall[NUM_BALLS];

void setup() {
  size(MAX_X, MAX_Y, P2D);
  smooth();

  // create some balls
  for(int i=0; i<NUM_BALLS; i++)
    balls[i] = new FlyingBall(int(random(MAX_X/36,MAX_X/12)), DURATION);
}

void draw() {
  background(#444444);

  // draw connecting lines
  stroke(#888888, 128);
  strokeWeight(2);
  for(int i=0; i<NUM_BALLS; i++) {
    line(balls[i].currentX, balls[i].currentY, balls[(i+1) % NUM_BALLS].currentX, balls[(i+1) % NUM_BALLS].currentY);
    line(balls[i].currentX, balls[i].currentY, balls[(i+3) % NUM_BALLS].currentX, balls[(i+3) % NUM_BALLS].currentY);
  }

  // draw balls
  noStroke();
  fill(#eeeeee, 128);
  for(int i=0; i<NUM_BALLS; i++)
    balls[i].draw();
}

// class to represent a ball
class FlyingBall {
  int sourceX=MAX_X/2, sourceY=MAX_Y/2;
  int targetX=MAX_X/2, targetY=MAX_Y/2;
  int currentX, currentY;
  int flySteps, currentStep;
  int size;

  FlyingBall(int size, int steps) {
    this.size = size;
    this.flySteps = steps;
    newTarget();
  }

  void draw() {
    currentX = interpol(sourceX, targetX, currentStep, flySteps);
    currentY = interpol(sourceY, targetY, currentStep, flySteps);

    ellipse(currentX, currentY, size, size);

    if(currentStep++ > flySteps)
      newTarget();
  }

  int interpol(int source, int target, int currentStep, int totalSteps) {
    float v = currentStep / (float)totalSteps;
    // smoothstep twice
    v = v*v*(3-2*v);
    v = v*v*(3-2*v);
    return int(source + (target-source)*v + .5);
  }

  void newTarget() {
    sourceX = targetX;
    sourceY = targetY;
    targetX = (int)random(size/2, MAX_X-size/2);
    targetY = (int)random(size/2, MAX_Y-size/2);
    currentStep = 0;
  }
}